Academic Score
/* TargetX ÅCADEMIC Score - Max of 10 points to start; Deductions or Additions then assessed for each student */
ROUND(10-
/* Overall GPA (Deduction) - 7 possible points */
(7 *
IF(Cumulative_GPA_Formula__c > 0,IF(Cumulative_GPA_Formula__c < 2.0, 1.00,
IF(Cumulative_GPA_Formula__c < 3.0, 0.75,
IF(Cumulative_GPA_Formula__c < 3.5, 0.50, 0))),0))
-
/* Withdrawals (Deduction) - 2 possible points */
(2 *
IF( Course_Withdrawals_RollUp__c >= 3, 1.00,
IF( TEXT(TgtX_Retention__Class_Level__c) = 'Sophmore' && Course_Withdrawals_RollUp__c >= 2, 0.75,
IF( TEXT(TgtX_Retention__Class_Level__c) = 'Freshman' && Course_Withdrawals_RollUp__c >= 1, 0.50,0))))
-
/* MidTerm Grades (Deduction) - 2 possible points */
(2 *
IF( MidTerm_Grades_Below_Avg_RollUp__c >= 6, 1.00,
IF( TEXT(TgtX_Retention__Class_Level__c) = 'Junior' && MidTerm_Grades_Below_Avg_RollUp__c >= 4, 0.50,
IF( TEXT(TgtX_Retention__Class_Level__c) = 'Sophmore' && MidTerm_Grades_Below_Avg_RollUp__c >= 2, 0.50,
IF( TEXT(TgtX_Retention__Class_Level__c) = 'Freshman' && MidTerm_Grades_Below_Avg_RollUp__c >= 1, 0.50,0)))))
-
/* Progression (Deduction) - 1 possible points */
(1 *
IF( (TEXT(TgtX_Retention__Class_Level__c) = 'Freshman' && (VALUE(TgtX_Retention__Expected_Graduation_Year__c) - YEAR(TODAY()) <= 2)), 1.00,
IF( ((TEXT(TgtX_Retention__Class_Level__c) = 'Sophomore') && (VALUE(TgtX_Retention__Expected_Graduation_Year__c) - YEAR(TODAY()) <= 1)), 1.00,0)))
,0)
Engagement Score
/* TargetX ENGAGEMENT Score - Max of 10 points to start; Deductions or Additions then assessed for each student */
ROUND(10-
/* Attendance (Deduction) - 6 possible points */
(6 *
IF( Course_Absences_RollUp__c >= 45, 1.00,
IF( TEXT(TgtX_Retention__Class_Level__c) = 'Sophomore' && Course_Absences_RollUp__c >= 30, 0.50,
IF( TEXT(TgtX_Retention__Class_Level__c) = 'Freshman' && Course_Absences_RollUp__c >= 15 , 0.50, 0))))
-
/* Action Items (Deduction) - 4 possible points */
(4 *
IF( (Action_Items_Open_RollUp__c/IF(Action_Items_Open_RollUp__c > 0 || Action_Items_Completed_RollUp__c > 0, Action_Items_Open_RollUp__c+Action_Items_Completed_RollUp__c,1)) > 0.75, 1.00,
IF((Action_Items_Open_RollUp__c/IF(Action_Items_Open_RollUp__c > 0 || Action_Items_Completed_RollUp__c > 0, Action_Items_Open_RollUp__c+Action_Items_Completed_RollUp__c,1)) > 0.50, 0.50, 0)))
/* Activities and Interests (Deduction) - TBD possible points. If included, will need to reassess points deducted for sections above. */
/* EXAMPLE:
<<If # of 'Active' Activities and Interests below desired threshold>>
*/
/* Surveys Completed (Addition) - TBD possible points. If included, will need to reassess points deducted for sections above. */
/* EXAMPLE:
<<Surveys Completed>>
*/
,0)
Financial Score
/* TargetX FINANCIAL Score - Max of 10 points to start; Deductions or Additions then assessed for each student */
10-
/* Financial Hold (Deduction) */
IF( TgtX_Retention__Total_Holds_Financial__c >= 3, 6,
IF( TgtX_Retention__Filtered_Holds_Financial__c >= 1, 4,0))
